## Veľkosť plochy ohraničenej grafom funkcie a osou x na intervale (a,b)

load(draw);

plocha(a,b):=integrate(f(x),x,a,b);

graf(a,b):=draw2d(
    xaxis = true, xaxis_width = 2, xaxis_type = solid, xaxis_color = black,
    yaxis = true, yaxis_width = 2, yaxis_type = solid, yaxis_color = black,
    transparent=true,
    fill_color = red,
    filled_func = f(x),
    explicit(0,x,a,b),
    transparent=true,
    filled_func = false,
    line_width = 2,
    color = blue,
    explicit(f(x),x,a-a/2,b+a/2)
    )$

Určte veľkosť plochy ohraničenej grafom funkcie f:y=sin x a osou x na intervale (π/4,π/2).

f(x):=sin(x);

a:%pi/4;

b:%pi/2;

graf(a,b);

plocha(a,b);

### Graf funkcie leží pod osou x.

Určte veľkosť plochy ohraničenej grafom funkcie f:y=cos x a osou x na intervale (π/4,π).

f(x):=cos(x);

b:%pi;

graf(a,b);

solve(f(x),x);

c:rhs(%[1]);

plocha(a,c)-plocha(c,b);

## Veľkosť plochy ohraničenej krivkou danou parametricky

graf2(a,b):=draw2d(nticks=200,parametric(phi(t),psi(t),t,a,b),proportional_axes=xy);

plocha2(a,b):=abs(integrate(psi(t)*diff(phi(t),t,1),t,a,b));

Veľkosť plochy ohraničenej kardioidou

phi(t):=2*cos(t)-cos(2*t)$

psi(t):=2*sin(t)-sin(2*t)$

a:0;

b:2*%pi;

graf2(0,2*%pi);

plocha2(a,b);

Veľkosť plochy ohraničenej jedným oblúkom cykloidy

phi(t):=t-sin(t)$

psi(t):=1-cos(t)$

a:0;

b:2*%pi;

graf2(a,b);

plocha2(a,b);

Veľkosť plochy ohraničenej jedným oblúkom nefroidy

phi(t):=3*cos(t)-cos(3*t)$

psi(t):=3*sin(t)-sin(3*t)$

a:0;

b:%pi;

graf2(a,b);

plocha2(a,b);

## Veľkosť plochy ohraničenej krivkou danou polárne

graf3(a,b):=draw2d(nticks=200,polar(rho(phi),phi,a,b),proportional_axes=xy);

plocha3(a,b):=1/2*integrate((rho(phi))^2,phi,a,b);

Veľkosť plochy ohraničenej kardioidou

rho(phi):=2*(1+cos(phi))$

a:0;

b:2*%pi;

graf3(a,b);

plocha3(a,b);

Veľkosť plochy ohraničenej "ružicovou" krivkou

rho(phi):=3*cos(7*phi);

graf3(a,b);

plocha3(a,b);

Veľkosť plochy vnútornej slučky krivky ρ=2+4*cosφ

rho(phi):=2+4*cos(phi);

graf3(a,b);

to_poly_solve([2+4*cos(t)=0], [t]);

a:2*%pi/3;

b:4*%pi/3;

graf3(a,b);

## Dĺžka krivky určenej rovnicou y=f(x) na intervale (a,b)

dlzka(a,b):=integrate(sqrt(1+(diff(f(x),x,1))^2),x,a,b);

f(x):=log(x);

a:1;

b:%e;

dlzka(a,b);

## Dĺžka krivky danej parametricky

dlzka2(a,b):=abs(integrate(sqrt(diff(phi(t),t,1)^2+(diff(psi(t),t,1))^2),t,a,b));

Dĺžka kardioidy

phi(t):=2*cos(t)-cos(2*t)$

psi(t):=2*sin(t)-sin(2*t)$

a:0;

b:2*%pi;

dlzka2(a,b);

Dĺžka jedného oblúka nefroidy

phi(t):=3*cos(t)-cos(3*t)$

psi(t):=3*sin(t)-sin(3*t)$

a:0;

b:%pi;

dlzka2(a,b);

## Dĺžka krivky danej polárnymi súradnicami

dlzka3(a,b):=integrate(sqrt((rho(phi))^2+(diff(rho(phi),phi,1))^2),phi,a,b);

Dĺžka kardioidy

rho(phi):=2*(1+cos(phi))$

a:0;

b:2*%pi;

## Objem rotačného telesa vzniklého rotáciou grafu y=f(x) okolo osi x na intervale (a,b)

objem(a,b):=%pi*integrate((f(x))^2,x,a,b);

Objem telesa vzniklého rotáciou grafu funkcie y=sin x okolo osi x na intervale (0,π)

f(x):=sin(x);

a:0;

b:%pi;

objem(a,b);

## Objem telesa vzniklého rotáciou krivky danej parametricky

objem2(a,b):=%pi*abs(integrate((psi(t))^2*diff(phi(t),t,1),t,a,b));

Objem telesa, ktoré vznikne rotáciou kardioidy

phi(t):=2*cos(t)-cos(2*t)$

psi(t):=2*sin(t)-sin(2*t)$

a:0;

b:%pi;

Z dôvodu symetrie teleso vzniká len rotáciou jedného oblúka nad osou x

objem2(a,b);

## Objem telesa, ktoré vznikne rotáciou krivky danej polárne

objem3(a,b):=2*%pi/3*integrate((rho(phi))^3*sin(phi),phi,a,b);

Objem telesa, ktoré vzniká rotáciou väčšiho oblúka kardioidy okolo osi x

rho(phi):=2*(1-cos(phi));

a:%pi/2; b:%pi;

objem3(a,b);

## Plocha plášťa rotačného telesa 
- funkcia daná explicitne

povrch(a,b):=2*%pi*integrate(f(x)*sqrt(1+(diff(f(x),x,1))^2),x,a,b);

Povrch telesa, ktoré vznikne rotáciou praboly
y=√x na intervale (0,2) okolo osi x

draw3d(
axis_3d=false,
dimensions=[800,800],
view=[80,10],
xrange=[0,2],
yrange=[-2,2],
color=black,
nticks=800,
parametric_surface(r,sqrt(r)*cos(t),sqrt(r)*sin(t),r,0,2,t,0,2*%pi)
    );

f(x):=sqrt(x);

a:0;

b:2;

povrch(a,b);

Určte plochu plášťa telesa, ktoré vznikne rotáciou grafu funkcie
 f:y=cosh x okolo osi x na intervale (-2,2).

draw3d(
axis_3d=false,
dimensions=[800,800],
view=[80,10],
xrange=[-2.2,2.2],
yrange=[-4,4],
zrange=[-4,4],
line_width=2,
color=black,
    parametric(t,0,0,t,-2.2,2.2),
    parametric(0,t,0,t,-2.2,2.2),
    parametric(0,0,t,t,-2.2,2.2),
nticks=800,
color=dark_red,    
parametric_surface(r,cosh(r)*cos(t),cosh(r)*sin(t),r,-2,2,t,0,2*%pi)
    );

obraz1:gr2d(
    nticks=400,
    color=blue,
    xrange=[-2.2,2.2],
    yrange=[0,4],
    line_width=2,
    explicit(cosh(x),x,-2,2)
);

obraz2:gr3d(
axis_3d=false,
dimensions=[800,800],
view=[80,10],
xrange=[-2.2,2.2],
yrange=[-4,4],
zrange=[-4,4],
line_width=2,
color=black,
    parametric(t,0,0,t,-2.2,2.2),
    parametric(0,t,0,t,-2.2,2.2),
    parametric(0,0,t,t,-2.2,2.2),
nticks=800,
color=dark_red,    
parametric_surface(r,cosh(r)*cos(t),cosh(r)*sin(t),r,-2,2,t,0,2*%pi)
);

wxdraw(obraz1,obraz2,columns=2);

f(x):=cosh(x);

a:-2;

b:2;

povrch(a,b);

%,numer;

## Plocha plášťa rotačného telesa 
- krivka daná parametricky

povrch2(a,b):=2*%pi*abs(integrate(psi(t)*sqrt(diff(phi(t),t,1)^2+(diff(psi(t),t,1))^2),t,a,b));

Povrh telesa, ktoré vznikne rotáciou kardioidy okolo osi x

phi(t):=2*cos(t)-cos(2*t)$

psi(t):=2*sin(t)-sin(2*t)$

Z dôvodu symetrie počítame len na intervale (0,π)

draw3d(
axis_3d=false,
    xu_grid=40,
    yv_grid=40,
dimensions=[800,800],
view=[80,10],
xrange=[-3.2,3.2],
yrange=[-3,3],
zrange=[-3,3],
line_width=2,
color=black,
    parametric(t,0,0,t,-3.2,3.2),
    parametric(0,t,0,t,-3.2,3.2),
    parametric(0,0,t,t,-3.2,3.2),
nticks=800,
color=dark_red,    
parametric_surface(2*cos(r)-cos(2*r),(2*sin(r)-sin(2*r))*cos(t),(2*sin(r)-sin(2*r))*sin(t),r,0,%pi,t,0,2*%pi)    
);

povrch2(0,%pi);

## Plocha plášťa rotačného telesa 
- krivka daná polárne

povrch3(a,b):=2*%pi*integrate(rho(phi)*sin(phi)*sqrt((rho(phi))^2+(diff(rho(phi),phi,1))^2),phi,a,b);

Povrch telesa, ktoré vznikne rotáciou Bernoulliho lemniskáty

rho(phi):=sqrt(cos(2*phi));

draw3d(
axis_3d=false,
    xu_grid=200,
    yv_grid=30,
dimensions=[800,800],
view=[80,10],
xrange=[-1,1],
yrange=[-1,1],
zrange=[-1,1],
line_width=1,
color=black,
    parametric(t,0,0,t,-1,1),
    parametric(0,t,0,t,-1,1),
    parametric(0,0,t,t,-0.7,0.7),
nticks=800,
color=dark_red,    
parametric_surface(rho(phi)*cos(phi),rho(phi)*sin(phi)*cos(t),rho(phi)*sin(phi)*sin(t),phi,0,2*%pi,t,0,2*%pi)    
);

povrch3(0,%pi);