## Bodová konvergencia

### Postupnosti funkcií

Vyšetríme obor konvergencie postupnosti funkcií f_n(x)=x^n,
Odhadneme limitnú funkciu.

Definujeme funkcie:

f(x,n):=x^n;

Pomocou príkazu plot2d si zobrazíme grafy funkcií f(x,n) pre viaceré honoty n.
Pri stanovení rozsahu pre premennú x treba zohľadniť, že príslušné mocniny môžu
pre veľké hodnoty n nadobúdať vysoké hodnoty a veľký rozsah hodnôt môže
úplne znehodnotiť výpovednú hodnotu grafu.(Napríklad hodnoty 0.9^50=0.00515...
ale  1.1^50=117.39... Tieto hodnoty sa majú zobraziť na jednom grafe!

plot2d([f(x,1),f(x,2),f(x,5),f(x,10)],[x,-1.5,1.5]);

Už na tomto obrázku môžeme pozorovať, že všetky krivky sa pretínajú v bodoch
so súradnicami [1,1] a [0,0]. Ďalej sa niektoré pretínajú v bode [-1,1] 
a ostatné v bode [-1,-1] (posúďte podľa parity n). 
Pre hodnoty x>1 pozorujeme pomerne prudký rast hodnôt x^n, podobne pre x<-1
môžeme pozorovať, ako sa krivky "rozbiehajú" ku vysokým kladným a záporným hodnotám.

Pozorovanie si potvrďme ďalším grafom pre vyššie hodnoty n.
snažíme sa voliť hodnoty s rôznymi paritami.

plot2d([f(x,5),f(x,10),f(x,21),f(x,50),f(x,101)],[x,-1.01,1.01]);

Môžeme teda dedukovať, že obor konvergencie je interval (-1,1>. Tento výsledok
je ľahko overiteľný priamym výpočtom limity lim x^n pre n→∞ a diskusiou vyhľadom na x.
Pre x=1 je lim x^n=1, pre x>1 je lim x^n=∞, pre x∈(-1,1) je lilm x^n=0
a konečne pre x≤-1 lim x^n neexistuje.

Z uvedeného môžeme tiež uzavrieť, že limitná funkcia g(x) má je definovaná tak,
g(x)=0 pre x∈(-1,1) a g(x)=1.

g(x):=if x<1 and x>-1 then 0;

bod:[discrete,[1,1]];

V grafe si zobrazíme limitnú funkciu a vybranú funkciu z postupnosti. Využijeme knižnicu draw.

load(draw);

To nám umožní zobraziť viacero funkcií z postupnosti a limitnú funkciu do jedného obrázku s odlišnými voľbami farby a hrúbky čiary,
resp. veľkosti bodu oynačujúceho súradnice [1,1]. Nastavením voľby yrange prispôsobíme rozsah zobrazeného úseku osi y tak,
aby mal obrázok zachovanú výpovednú hodnotu. 

draw2d(
dimensions=[800,800],
color=black,
explicit(f(x,10),x,-1.02,1.05),
explicit(f(x,21),x,-1.02,1.05),    
explicit(f(x,50),x,-1.02,1.05),    
explicit(f(x,101),x,-1.02,1.05),    
explicit(f(x,200),x,-1.02,1.05),
color=blue,
line_width=2,
explicit(g(x),x,-1.01,1.01),
point_type=filled_circle,
point_size=2,        
points([[1,1]]),
yrange=[-0.5,5]      
);

Predchídzajúci postup a úvahy použite na vyšetrenie nižšie definovaných postupností funkcií 
a určenie ich oboru konvergencie resp. limitnej funkcie.
Pozor, pri zobrazovaní limitnej funkcie g(x) je nezabudnite predefinovať adekvátne ku získanému
riešenie, príp. dodefinovať jej izolované body a prispôsobiť rozsah hodnôt yrange.

f(x,n):=(1-x^2)^n;

f(x,n):=1/(1+n*x^2);

f(x,n):=(2/%pi)*atan(n*x);

f(x,n):=(1+x/n)^n;

### Rady funkcií

Podobne ako pri číselných radoch definujeme súčet radu ako limitu postupnosti
čiastočných súčtov. Definujeme preto funkciu čiastočného súčtu.

s(n,x):=sum(f(x,k),k,1,n);

Určme obor konvergencie a súčet radu ∑(ln x)^n, n=1,...,∞.

f(x,n):= (log(x))^n;

Zobrazme si nieekoľko členov postupnosti čiastočných súčtov. Pri stanovení
rozsahu hodnôt premennej x treba dbať na skutočnosť, že logaritmy sú definované
len pre kladné čísla. tiež treba zohľadniť limity na možné funkčné hodnoty,
aby príliš veľký rozsah neviedol k znehodnoteniu grafického výstupu.

plot2d([s(1,x),s(2,x),s(5,x),s(10,x),s(20,x)],[x,0.35,2.8]);

plot2d([s(10,x),s(20,x),s(50,x),s(100,x),s(200,x)],[x,0.36,2.73]);

Experimentovaním s dolnou hranicou pre x medzi 0.35 a 0.38 
a s hornou hranicou pre x medzi 2.70 a 2.75 dospejeme k názoru,
že funkčný rad konverguje na nejakom podintervale intervalu (0.35,2.75).

Ak podrobne analyzujeme daný rad 
ln x + (ln x)^2 + (ln x)^3 + ... + (ln x)^n + ...
tak vidíme, že ide o geometrický rad s kvocientom q=ln x. 
tento rad konverguje ak |q|<1, teda |ln x|<1. Teda ak x∈(1/e,e).
vieme aj určiť súčet tohto geometrického radu, ktorý je
ln x/(1 - ln x).

g(x):=if x>1/%e and x<%e then log(x)/(1-log(x));

Definovanú súčtovú funkciu g(x) a niekoľko čiastkových súčtov
zobrazíme v jednom obrázku. 
Tu vidíme, ako rýchlo rad konverguje ku svojmu súčtu.
V blízkosti krajných bodov oboru konvergencie poterbujeme
spočítať stále viac členov čiastočného súčtu.

draw2d(
dimensions=[800,800],
color=black,
explicit(s(10,x),x,0.35,2.8),
explicit(s(20,x),x,0.35,2.8),    
explicit(s(50,x),x,0.35,2.8),    
explicit(s(100,x),x,0.35,2.8),    
explicit(s(200,x),x,0.35,2.8),
color=blue,
line_width=2,
explicit(g(x),x,0.35,2.75),
points([[1,1]]),
yrange=[-10,300]      
);

Postup opakujte s nižšie definovanými funkčnými radmi.

f(x,n):=x^n;

f(x,n):=1/(3*x^2+4*x+2)^n;

Pre vyštrenie oboru konvergencie funkčných radov môžeme využiť kritériá konvergencie
číselných radov s nezápornými členmi, ktoré využijeme ak kritériá absolútnej konvergencie.
Vyšetríme obor konvergencie radu:

f(x,n):=(x+1)^n/(n*2^n);

Definujeme kriteriálnu funkciu pre podielové kritérium:

ga(x):=f(x,n+1)/f(x,n);

Aplikujeme na náš prípad:

ga(x);

Teraz využijeme limitný tvar kritéria, pri tom zohľadníme to, že vyšetrujeme
absolútnu konvergenciu.

limit(abs(ga(x)),n,inf);

Podľa pravidiel kritéria musí byť výsledná limita <1. Ľahkio teda overíme,
že x∈(-3,1). Treba ešte vyšetriť konvergenciu v krajných bodoch intervalu.
(Tu je výsledná limita rovná 1 a kritérium neumožňuje rozhodnúť o konvergencii).
Ak je teda x=1, dostaneme členy: 

f(1,n);

Výsledkom je teda harmonický rad, ktorý diverguje.
Podobne dosaďme x=-3:

f(-3,n);

Ak upravíme mocniny, dostávame:

radcan(%);

Výsledkom je teda Leibnizov rad, o ktorom vieme, že je relatívne konvergentný.
celkom je teda obor konvergecie M=<-3,1).

Vyšetríme konvergenciu funkčného radu s členmi:

f(x,n):=exp(-n^2*x);

V tomto prípade je lepšie použiť odmocninové (Cauchyho) kritérium:

gc(x):=(f(x,n))^(1/n);

Vzhľadom na vlastnosti exponenciálnej funkcie je náš funkčný rad
radom s nezápornými členmi, tekže kritérium môžeme použiť priamo,
bez absolútnych hodnôt. Máme.

gc(x);

Vypočítame limitu kriteriálnej hodnoty, pri tom budeme musieť
rozlišovať kladné, záporné a nulové hodnoty x:

V prvom výpočte odpovieme positive

limit(gc(x),n,inf);

V druhom výpočte odpovieme zero

limit(gc(x),n,inf);

Konečne pri treťom výpočte odpovieme negative

limit(gc(x),n,inf);

Teda vidíme, že rad konverguje pre x>0 a diverguje pre x<0.
Ostáva vyšetriť hraničnú hodnotu x=0.

f(0,n);

Ako vidíme, pre x=0 dostávame konštantnú postupnosť a príslušný rad diverguje,
lebo nie je splnená nutná podmienka konvergencie.
Celkom teda konštatujeme, že obodr konvergencie M=(0,∞).

Postup opakujte pre nasledujúce funkčné rady. Nezabúdajte na vhodný
výber kritéria konvergencie.

f(x,n):=x^n/n^n;

f(x,n):=x^n/(n*(n+1));

f(x,n):=n/((n+1)*(3*x^2+4*x+2)^n);

f(x,n):=((x*(x+n))/n)^n;

f(x,n):=n*exp(-n*x);