## Mocninový rad

### Polomer konvergencie

Mocninové rady sú funkčné rady, ktoré majú tvar ∑a(n)x^n, n=1,...,∞.
Pri vyšetrovaní ich konvergencie sa sústreďujeme na koeficienty a(n).
Polomer konvergencie r definujeme ako 1/a, kde a=lim sup (a(n))^(1/n).
Pozn.: Pokiaľ existuje lim a(n) tak existuje aj lim sup a(n) a sú rovnaké,
pri väčšine úloh tak vystačíme s výpočtom limity. 

Určme polomer konvergencie radu

s(n,x):=sum((1+1/n)^(n^2)*x^n,n,1,inf);

Z radu vyberieme jeho koeficienty

a(n):=(1+1/n)^(n^2);

Tieto koeficienty využijeme na výpočet polomeru konvergencie:

limit(1/(a(n))^(1/n),n,inf);

Polomer konvergencie je teda 1/e. Ešte vyšetríme konvergenciu v krajných
bodoch konvergenčného intervalu:

Ak do radu dosadíme x=1/e, dostaneme rad:

s(n,1/%e);

limit(a(n)*exp(-n),n,inf);

Limita je nenulová, teda nie je splnená nutná podmienka konvergencie.

Po dosadení x=-1/e dostaneme

s(n,-1/%e);

Toto je alternujúci rad, z predchádzajúceho výpočtu vieme,
že lim a(n)≠0, teda rad nie je konvergentný.

Obor konvergencie je teda M=(-1/e,1/e).

Postup aplikujte na nasledujúce mocninové rady.
Pozn.: pri niektorých úlohách využite vzťah rovnosti medzi
limitami lim a(n+1)/a(n) a lim (a(n))^(1/n).

s(n,x):=sum(x^n/n,n,1,inf);

s(n,x):=sum(2^n/n^2*x^n,n,1,inf);

s(n,x):=sum(n*x^n/n!,n,1,inf);

s(n,x):=sum(x^n/((n+1)*5^n),n,1,inf);

s(n,x):=sum(2^n*x^n,n,1,inf);

### Súčet mocninového radu

Určme polomer konvergencie a súčet mocninového radu:

s(n,x):=sum(x^(4*n-3)/(4*n-3),n,1,inf);

Koeficienty radu sú:

a(n):=1/(4*n-3);

limit(1/(a(n))^(1/n),n,inf);

Polomer konvergencie je teda r=1.

Všimnime si, že derivovaním radu člen o člene dostaneme:

diff(x^(4*n-3)*a(n),x,1);

Vzhľadom na rovnomernosť konvergencie mocninových radov
nám stačí určiť súčet radu,ktorý vznikne derivovaním člen po člene.
Pôvodný súčet potom určíme integráciou získaného súčtu.

Pretože rad ∑x^(4n-4) je geometrický rad s kvocientom x^4,
konverguje pre |x|<1 ku svojmu súčtu:

sucet(x):=(1/(1-x^4));

Hľadaný súčet pôvodného radu teda je

integrate(sucet(x),x);

Určme polomer konvergencie a súčet radu

s(n,x):=sum(n*(n+2)*x^n,n,1,inf);

Koeficienty mocnonového radu majú tvar

a(n):=n*(n+2);

a polomer konvergencie je preto r=1:

limit(1/(a(n))^(1/n),n,inf);

Pre určnie súčtu radu si všimnime, že platí

diff(x^(n+2),x,1);

a preto odvodíme

1/x*diff(x^(n+2),x,1);

Opätovným derivovaním dostaneme

diff(1/x*diff(x^(n+2),x,1),x,1);

a odtiaľ pre n-tý člen nášho radu máme

x*diff(1/x*diff(x^(n+2),x,1),x,1);

Mocninový rad, ktorého súčet máme určiť teda zapíšeme v tvare
x(1/x*(∑ x^(n+2))')'

Rad ∑ x^(n+2) je geometrický rad s kvocientom x a začiatočným
členom x^3. Jeho súčet je teda

sucet(x):=x^3/(1-x);

Pre súčet pôvodného radu tak dostávame

vysledok(x):=ratsimp(x*diff(1/x*diff(sucet(x),x,1),x,1));

vysledok(x);

To môžeme upraviť do podoby:

factor(vysledok(x));

Náš výsledok je možné využiť na určenie súčtu niektorých číselných radov.
Ak napríklad dosadíme x=1/3, dostaneme rad

s(n,1/3);

Jeho súčet potom určíme dosadením x=1/x do súčtu nášho mocninového radu.
Použijeme funkciu subst; s jej pomocou nahradíme hodnotu x hodnotou 1/3:

subst(1/3, x, vysledok(x));

### Taylorov a McLaurinov rad

Funkciu ln(1+x) vyjadríme ako mocninový rad a s jeho pomocou určme
súčet Leibnizovho radu ∑(-1)^(n-1) * 1/n.

Pretože platí

diff(log(1+x),x,1);

môžeme využiť rozvoj radu 1/(1+x), čo je vlastne súčet geometrického
radu s prvým členom 1 a kvocientom x. tento rad získame tiež pomocou
funkcie taylor:

taylor(1/(1+x), x, 0, 10);

Ak teda definujeme:

g(x):=sum((-x)^n,n,0,inf);

tak integráciou máme

integrate(g(x),x);

Ak posunieme sčítací index tak, aby začínal od hodnoty 1,
dostávame:

sum((-1)^(n-1)*x^n/n,n,0,inf);

čo pre n=1 dáva Leibnizov rad a jeho súčet je teda:

limit(log(1+x),x,1,minus);

Určme McLaurinov rad funkcie e^(-x^2).

Využijeme zanolsť Mclaurinovho rozvoja funkcie e^x:

T(x):=taylor(exp(x),x,0,10);

T(x);

Aby sme nemuseli počítať derivácie e^(-x^2),
do predchádzajúceho rozvoja dosadíme -x^2 za x:

subst(-x^2,x,T(x));

Porovnajme ešte s výstupom funkcie taylor:

taylor(exp(-x^2),x,0,20);

Určme hodnotu sin 18° s chymou menšou ako 10^(-4).

Využijeme znalosť McLaurinovho radu funkcie sin(x):

sum((-1)^n*x^(2*n+1)/(2*n+1)!,n,0,inf);

Musíme teda určiť, pre ktoré hodnoty n už je n-tý člen tohto
radu menší ako požadovaná hodnota 10^(-4).
Preto definujeme:

f(n,x):=(-1)^n*x^(2*n+1)/(2*n+1)!;

Overíme si niekoľko hodnôt n pre dané x=π/10=18°.

subst(1,n,(subst(%pi/10,x,f(n,x))));

Overíme numerickú hodnotu

%,numer;

subst(2,n,(subst(%pi/10,x,f(n,x)))),numer;

Pre n=2 už dostávame hodnotu menšie ako 10^-4. Preto hľadaná honota
sin 18° je:

sum(subst(%pi/10,x,f(n,x)),n,0,1),numer;